OPTIONS LINESIZE=75 PAGESIZE=54 NODATE PAGENO=1;

DATA AX23;
 INPUT PERSON T1-T4;
CARDS;
1 72 86 81 77
2 78 83 88 81
3 71 82 81 75
4 72 83 83 69
5 66 79 77 66
6 74 83 84 77
7 62 73 78 70
8 69 75 76 70
DATA X; SET AX23; DROP PERSON;

PROC IML; RESET NOLOG;
TITLE 'Ex. 10.5 - Testing for the H-F Conditions.';

 USE X; READ ALL INTO X;
 N = NROW(X); P = NCOL(X);
 PRINT "X = " X;
 XBAR = (X[+,])`/N;
SUMSQ = X`*X - N#XBAR*XBAR`;
SIGHAT = SUMSQ/(N-1);
PRINT, "XBAR = " XBAR, "SIGHAT =" SIGHAT;
QQ=ORPOL(1:P,P-1);
PP=QQ(|1:P,2:P|);
SIGSTAR=PP`*SIGHAT*PP;
PRINT, "SIGSTAR = " SIGSTAR;
P=P-1;
LAMDA = DET(SIGSTAR)/(((1/P)#TRACE(SIGSTAR))**P);
M=N-1-(2#P#P+P+2)/(6#P);
A=(P+1)#(P-1)#(P+2)#(2#P#P#P+6#P#P+3#P+2)/(288#P#P);
F=P#(P+1)/2-1;
Z=-M#LOG(LAMDA);
PRINT, "Z = " Z;
ALPHA=(1-PROBCHI(Z,F))+(A/(M#M))#(PROBCHI(Z,F)-PROBCHI(Z,F+4));
PRINT, "LAMDA =" LAMDA, "ALPHA FOR H-F CONDITIONS = " ALPHA;
PRINT /;
TITLE 'Ex. 10.5 - Hotelling''s Test of no time effect.';

P=P+1;
     H = {1 -1 0 0,
          1 0 -1 0,
          1 0 0 -1};

     SMALLH = {0 0 0}`;
Q = NROW(H);
PRINT, "H = " H, "SMALLH = " SMALLH;
V = INV(H*SIGHAT*H`);
T2 = N#(H*XBAR - SMALLH)`*V*(H*XBAR - SMALLH);
F = (N - Q)#T2/(Q#(N - 1));
DFN = Q;
DFD = N - Q;
ALPHA = 1 - PROBF(F,DFN,DFD);
PRINT, "T2 = " T2, "F = " F, "DEGREES OF FREEDOM ARE" DFN DFD;
PRINT, "ALPHA = " ALPHA;

TITLE 'Ex. 10.5 - Using SAS-GLM with its REPEATED option';
PROC GLM;
 MODEL T1-T4 =/NOUNI;
 REPEATED TIME 4/PRINTE;
RUN;